Desktop Apps Silent Installation/Upgrade (6.6)

Views:

Question:
How to set up the silent DocuWare Desktop App install/upgrade?

Answer:
With DocuWare you are able to install/upgrade all DocuWare Desktop Apps silently.

DocuWare Desktop Apps:

DocuWare Desktop
- Printer App
- Import App
- Scanner App
- Smart Connect App
- Edit & Send App
- Connect to Outlook
- Windows Explorer Client
- Common OCR
Upload App
Workflow Designer App
Connect To Toshiba App

Prerequisites:

.NET Framework v4.5.1
Windows Installer 4.5
Visual C++ 2010 redistributable packages
- for x86 systems install only vcredist_x86.exe
- for x64 systems install only vcredist_x64.exe and vcredist_x86.exe
Visual C++ 2012 redistributable packages
- for x86 systems install only vcredist_x86.exe
- for x64 systems install only vcredist_x64.exe and vcredist_x86.exe

All prerequisites need to be installed manually and before installing the Desktop Apps silently. This is very important otherwise the Desktop Apps won't work.

You'll find the files in the folder [DW6.6Setup]\DocuWare and Modules\ClientSetup\Prerequisites\
How to perform a silent install of the Visual C++ 2010/2012 redistributable packages is described in this MSDN Blog: http://blogs.msdn.com/b/astebner/archive/2010/10/20/10078468.aspx

Steps to perform a silent installation of the DocuWare Desktop Apps:

1. Make sure that the directory C:\Program Files (x86)\DocuWare\Web\ClientSetupData\ is available over the network
2. Create a new text file in the setup directory and add the following content:

@echo off

echo  *************************************************************
echo  ** DocuWare 6.6 Desktop Apps are being installed ***
echo  **** This window will be closed automatically.**********
echo  *************************************************************

rem specify DWSetupPath, share folder C:\Program Files (x86)\DocuWare\Web\ClientSetupData. Needs to be accessible from the client pc!
SET DWSetupPath=\\servername\ClientSetupData

rem specify DWSettingsPath, e.g. http://dwsrv/DocuWare/Platform/Home/ClientSetupInfo?orgId=1. Usually the organization ID is 1.

rem You'll find the Org ID in DW Administration > Organization > General - Identifier
SET DWSettingsPath=http://servername/DocuWare/Platform/Home/ClientSetupInfo?orgId=1

rem add settings path for DW Desktop default connection management in registry (HKLM)
if defined ProgramFiles(x86) (set RegPath=HKLM\SOFTWARE\Wow6432Node) else (set RegPath=HKLM\SOFTWARE)
reg add %RegPath%\DocuWare\Setup /v SettingsPath /t REG_SZ /d %DWSettingsPath% /f >nul 2>&1


rem DW Desktop Plugins - start
	rem DW Desktop Framework with Common OCR is required for each DW Desktop App
	msiexec /i "%DWSetupPath%\DocuWare.Desktop.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_Des.log /q
	msiexec /i "%DWSetupPath%\DocuWare.CommonOCR.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_OCR.log /q

	rem DW Printer
	msiexec /i "%DWSetupPath%\DocuWare.Desktop.Printer.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_Pri.log /q

	rem DW Import
	msiexec /i "%DWSetupPath%\DocuWare.Desktop.Import.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_Imp.log /q

	rem DW Scanner
	msiexec /i "%DWSetupPath%\DocuWare.Desktop.Scanner.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_Sca.log /q

	rem Smart Connect
	msiexec /i "%DWSetupPath%\DocuWare.Desktop.SmartConnect.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_SC.log /q

	rem Edit & Send
	msiexec /i "%DWSetupPath%\DocuWare.Desktop.EditSend.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_EaS.log /q

	rem Connect to Outlook App
	msiexec /i "%DWSetupPath%\DocuWare.ConnectToOutlook.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_C2O.log /q

	rem Windows Explorer App
	rem for WEC you need to find out if x64 or not
	if defined ProgramFiles(x86) (set WECx64=DocuWare.WindowsExplorerClient64.msi) else (set WECx64=DocuWare.WindowsExplorerClient.msi)
	msiexec /i "%DWSetupPath%\%WECx64%" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_WEC.log /q

	rem start DW Desktop with params -createdefaultconnection to create a default connection
	if defined ProgramFiles(x86) (start "" "C:\Program Files (x86)\DocuWare\Desktop\DocuWare.Desktop.exe" -createdefaultconnection) else (start "" "C:\Program Files\DocuWare\Desktop\DocuWare.Desktop.exe" -createdefaultconnection)
rem DW Desktop Plugins - end


rem DocuWare Upload App 
	msiexec /i "%DWSetupPath%\DocuWare.UploadService.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_UpS.log /q

	
rem DocuWare Workflow Designer
	msiexec /i "%DWSetupPath%\DocuWare.WorkflowDesigner.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_WfD.log /q

	
rem Connect To Toshiba
	msiexec /i "%DWSetupPath%\DocuWare.ConnectToToshiba.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_C2T.log /q
 
rem logging is optional. Disable it by removing "/liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_Xxx.log"

3. Delete the corresponding rows for the apps which should not be installed.
4. Adapt the highlighted parts according to your installation.
5. Save the text file as e.g. DocuWare_66_Desktop_Apps_Silent_Install.bat
6. Run the BAT file manually or in a Windows logon script

Important notes:

Local Admin rights are required for the installation.
On terminalservers we recommend to add the parameter REBOOT=R, in order to prevent an automatic reboot of the server.
If there is no connection, DocuWare Desktop will automatically connect to the DocuWare System, 2 minutes after the start.
- Another option is to trigger the connection using the command line argument -createdefaultconnection for DocuWare.Desktop.exe. The connection is then established immediately at the start of DW Desktop (see example in the script above).
- If windows authentication is set up in DocuWare, no further action is required by the user.
- If windows authentication is not set up, the user will be prompted to enter his/her DocuWare credentials.
Starting with DocuWare 6.6 the connection management of Connect to Outlook App and Windows Explorer App is also handled by DocuWare Desktop. No further action is required.

For a silent uninstallation use this script:

@echo off

echo **************************************************************
echo *** DocuWare Desktop Apps are being uninstalled ****
echo **** This window will be closed automatically. **********
echo **************************************************************

rem specify DWSetupPath, share folder C:\Program Files (x86)\DocuWare\Web\ClientSetupData. Needs to be accessible from the client pc!
SET DWSetupPath=\\servername\ClientSetupData

rem delete settings in registry HKLM
if defined ProgramFiles(x86) (set RegPath=HKLM\SOFTWARE\Wow6432Node) else (set RegPath=HKLM\SOFTWARE)
reg delete %RegPath%\DocuWare\Setup /v SettingsPath /f >nul 2>&1

rem DW Desktop Plugins - start
rem DW Printer
	msiexec /x "%DWSetupPath%\DocuWare.Desktop.Printer.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_Pri.log /q
	rem DW Import
	msiexec /x "%DWSetupPath%\DocuWare.Desktop.Import.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_Imp.log /q
	rem DW Scanner
	msiexec /x "%DWSetupPath%\DocuWare.Desktop.Scanner.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_Sca.log /q
	rem Smart Connect
	msiexec /x "%DWSetupPath%\DocuWare.Desktop.SmartConnect.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_SC.log /q
	rem Edit & Send
	msiexec /x "%DWSetupPath%\DocuWare.Desktop.EditSend.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_EaS.log /q
	rem Connect to Outlook
	msiexec /x "%DWSetupPath%\DocuWare.ConnectToOutlook.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_C2O.log /q
	rem Windows Explorer App
 rem for WEC you need to find out if x64 or not
	if defined ProgramFiles(x86) (set WECx64=DocuWare.WindowsExplorerClient64.msi) else (set WECx64=DocuWare.WindowsExplorerClient.msi)
	msiexec /x "%DWSetupPath%\%WECx64%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_WEC.log /q
	rem DocuWare Desktop Framework with CommonOCR
	msiexec /x "%DWSetupPath%\DocuWare.Desktop.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_Des.log /q
	msiexec /x "%DWSetupPath%\DocuWare.CommonOCR.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_OCR.log /q
rem DW Desktop Plugins - end

rem DocuWare Upload App
msiexec /x "%DWSetupPath%\DocuWare.UploadService.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_UpS.log /q

rem DocuWare Workflow Designer
msiexec /x "%DWSetupPath%\DocuWare.WorkflowDesigner.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_WfD.log /q

rem Connect To Toshiba
msiexec /x "%DWSetupPath%\DocuWare.ConnectToToshiba.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_C2T.log /q

This article is valid for DocuWare versions: 6.6 | silent installation uninstall setup #FAQID_3528

Desktop Apps Silent Installation/Upgrade (6.6)

Get Help