Ansichten:

Frage:

Wie installiere ich die Desktop Apps mit dem Silent Setup in DocuWare 6.7?

Antwort:

Alle Voraussetzungen müssen manuell und vor den Desktop Apps installiert werden. Dies ist wichtig da die Desktop Apps ansonsten nicht korrekt funktionieren!
Alle benötigten Dateien dazu finden Sie im Ordner...\DocuWare\Server\Web\ClientSetupData\Prerequisites\

Voraussetzungen:

  • .NET Framework v 4.5
  • Windows Installer 4.5
  • Visual C++ 2008 redistributable packages
  • auf x86 Systeme installieren Sie nur vcredist_x86.exe
  • auf x64 Systeme installieren Sie vcredist_x64.exe und vcredist_x86.exe
  • Visual C++ 2010 redistributable packages
  • auf x86 Systeme installieren Sie nur vcredist_x86.exe
  • auf x64 Systeme installieren Sie vcredist_x64.exe und vcredist_x86.exe
  • Visual C++ 2012 redistributable packages
  • auf x86 Systeme installieren Sie nur vcredist_x86.exe
  • auf x64 Systeme installieren Sie vcredist_x64.exe und vcredist_x86.exe

​DocuWare Desktop Apps:

  • DocuWare Desktop
  • Printer App
  • Import App
  • Scanner App
  • Smart Connect App
  • Edit & Send App
  • Connect to Outlook
  • Windows Explorer Client
  • Common OCR
  • Upload App
  • Workflow Designer App
  • Connect To Toshiba App 

Führen Sie folgende Schritte durch;

1. Stellen Sie sicher, dass das  Verzeichnis ...\DocuWare\Web\ClientSetupData\ im Netzwerk zur Verfügung steht. Geben Sie es ggf. frei.

2. Erstellen Sie darin eine neue Textdatei und fügen Sie folgenden Inhalt hinzu:

@echo off

echo ****************************************************
echo ** DocuWare 6.7 Desktop Apps are being installed ***
echo **** This window will be closed automatically. *****
echo ****************************************************

rem specify DWSetupPath, share folder C:\Program Files (x86)\DocuWare\Web\ClientSetupData\. Needs to be accessible from the client pc!
SET DWSetupPath=\\servername\ClientSetupData

rem specify DWSettingsPath, e.g. http://dwsrv/DocuWare/Platform/Home/ClientSetupInfo?orgId=1. Usually the organization ID is 1.

rem You'll find the Org ID in DocuWare Administration > Organization > General - Identifier
SET DWSettingsPath=http://servername/DocuWare/Platform/Home/ClientSetupInfo?orgId=1

rem add settings path for DocuWare Desktop default connection management in registry (HKLM)
if defined ProgramFiles(x86) (set RegPath=HKLM\SOFTWARE\Wow6432Node) else (set RegPath=HKLM\SOFTWARE)
reg add %RegPath%\DocuWare\Setup /v SettingsPath /t REG_SZ /d %DWSettingsPath% /f >nul 2>&1

rem DocuWare Desktop Plugins - start
rem DocuWare Desktop Framework with Common OCR is required for each DocuWare Desktop App
msiexec /i "%DWSetupPath%\DocuWare.Desktop.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_Des.log /q
msiexec /i "%DWSetupPath%\DocuWare.CommonOCR.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_OCR.log /q

rem DocuWare Printer
msiexec /i "%DWSetupPath%\DocuWare.Desktop.Printer.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_Pri.log /q

rem DocuWare Import
msiexec /i "%DWSetupPath%\DocuWare.Desktop.Import.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_Imp.log /q

rem DocuWare Scanner
msiexec /i "%DWSetupPath%\DocuWare.Desktop.Scanner.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_Sca.log /q

rem Smart Connect
msiexec /i "%DWSetupPath%\DocuWare.Desktop.SmartConnect.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_SC.log /q

rem Edit & Send
msiexec /i "%DWSetupPath%\DocuWare.Desktop.EditSend.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_EaS.log /q

rem Connect to Outlook App
msiexec /i "%DWSetupPath%\DocuWare.ConnectToOutlook.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_C2O.log /q

rem Windows Explorer App
rem for WEC you need to find out if x64 or not
if defined ProgramFiles(x86) (set WECx64=DocuWare.WindowsExplorerClient64.msi) else (set WECx64=DocuWare.WindowsExplorerClient.msi)
msiexec /i "%DWSetupPath%\%WECx64%" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_WEC.log /q

rem start DocuWare Desktop with params -createdefaultconnection to create a default connection and start DWDesktopService

net start DWDesktopService

if defined ProgramFiles(x86) (start "" "C:\Program Files (x86)\DocuWare\Desktop\DocuWare.Desktop.exe" -createdefaultconnection) else (start "" "C:\Program Files\DocuWare\Desktop\DocuWare.Desktop.exe" -createdefaultconnection)

rem DocuWare Desktop Plugins - end

rem DocuWare Upload App 
msiexec /i "%DWSetupPath%\DocuWare.UploadService.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_UpS.log /q

rem DocuWare Workflow Designer
msiexec /i "%DWSetupPath%\DocuWare.WorkflowDesigner.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_WfD.log /q
	
rem Connect To Toshiba
msiexec /i "%DWSetupPath%\DocuWare.ConnectToToshiba.msi" ALLUSERS=1 MSIFASTINSTALL=7 SETTINGSPATH="%DWSettingsPath%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_C2T.log /q
 
rem logging is optional. Disable it by removing "/liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Install_Xxx.log"

3. Löschen Sie ggf. die entsprechenden Zeilen wenn Sie Apps nicht installieren möchten.

4. Passen Sie die gelb markierten Stellen entsprechend Ihrer Installation an.

5. Speichern Sie die Textdatei z.B. unter DocuWare_67_Desktop_Apps_Silent_Install.bat

6. Rufen Sie die BAT Datei nun manuell auf oder binden Sie sie z.B. in ein Windows Logon Script ein.

Wichtige Hinweise:

  • Zur Installation werden lokale Administratorrechte vorausgesetzt
  • In Terminalserver-Umgebungen emfpehlen wir die Nutzung des Parameters REBOOT=R. Dadruch wird ein automatisches Neustarten des Servers verhindert.
  • Sollte keine Verbindung existieren, so wird die Verbindung von DocuWare Desktop zum DocuWare System automatisch, 2 Minuten nach dem Start von DocuWare Desktop hergestellt!
  • Sie können alternativ durch den Startparameter -createdefaultconnection die Verbindung sofort beim Start von DocuWare.Desktop.exe herstellen.
  • Ist die Windows Authentifizierung in DocuWare eingerichtet, sind keine weiteren Schritte des Benutzers erforderlich.
  • Wird DocuWare Authentifizierung verwendet, muss der Benutzer seine DocuWare Logindaten in den sich öffnenden Login Dialog eingeben,
Verwenden Sie folgendes Script um die DocuWare Desktop Apps zu deinstallieren:

@echo off 
echo ****************************************************
echo **** DocuWare Desktop Apps are being removed. *****
echo **** This window will be closed automatically. *****
echo ****************************************************
rem specify DWSetupPath, share folder C:\Program Files (x86)\DocuWare\Web\ClientSetupData. Needs to be accessible from the client pc!
SET DWSetupPath=\\servername\ClientSetupData

rem delete settings in registry HKLM
if defined ProgramFiles(x86) (set RegPath=HKLM\SOFTWARE\Wow6432Node) else (set RegPath=HKLM\SOFTWARE)
reg delete %RegPath%\DocuWare\Setup /v SettingsPath /f >nul 2>&1

rem DocuWare Desktop Plugins - start
rem DocuWare Printer
msiexec /x "%DWSetupPath%\DocuWare.Desktop.Printer.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_Pri.log /q

rem DocuWare Import
msiexec /x "%DWSetupPath%\DocuWare.Desktop.Import.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_Imp.log /q

rem DocuWare Scanner
msiexec /x "%DWSetupPath%\DocuWare.Desktop.Scanner.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_Sca.log /q
	
rem Smart Connect
msiexec /x "%DWSetupPath%\DocuWare.Desktop.SmartConnect.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_SC.log /q

rem Edit & Send
msiexec /x "%DWSetupPath%\DocuWare.Desktop.EditSend.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_EaS.log /q

rem Connect to Outlook
msiexec /x "%DWSetupPath%\DocuWare.ConnectToOutlook.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_C2O.log /q

rem Windows Explorer App
rem for WEC you need to find out if x64 or not
if defined ProgramFiles(x86) (set WECx64=DocuWare.WindowsExplorerClient64.msi) else (set WECx64=DocuWare.WindowsExplorerClient.msi)
msiexec /x "%DWSetupPath%\%WECx64%" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_WEC.log /q

rem DocuWare Desktop Framework with CommonOCR
msiexec /x "%DWSetupPath%\DocuWare.Desktop.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_Des.log /q

msiexec /x "%DWSetupPath%\DocuWare.CommonOCR.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_OCR.log /q

rem DocuWare Desktop Plugins - end

rem DocuWare Upload App
msiexec /x "%DWSetupPath%\DocuWare.UploadService.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_UpS.log /q

rem DocuWare Workflow Designer
msiexec /x "%DWSetupPath%\DocuWare.WorkflowDesigner.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_WfD.log /q

rem Connect To Toshiba
msiexec /x "%DWSetupPath%\DocuWare.ConnectToToshiba.msi" /liwearmo %temp%\DocuWare_Desktop_Apps_Silent_Uninstall_C2T.log /q
Dieser Artikel ist gültig für die DocuWare Versionen: 6.7 | silent installation silent setup desktop apps installation #FAQID_3792